Arduino Waveシールドを使ってみる

#include <WaveHC.h>
#include <WaveUtil.h>

#define PLAY_PIN 6
#define SELECT_PIN 7

#define error(msg) SerialPrint_P(PSTR(msg))

SdReader cardReader;
FatVolume volume;
FatReader root;
FatReader playFile;
WaveHC waveFile;

const char game_0[] PROGMEM = "maX.wav";
const char* const games[] PROGMEM = {game_0};
const PROGMEM char number[] = {‘1′,’2′,’3’};

char name[8];
uint8_t index = 1;
uint8_t lastPlayState = HIGH;
uint8_t lastSelectState = HIGH;
boolean isPlaying = false;

void setup() {
    Serial.begin(9600);
    pinMode(PLAY_PIN, INPUT_PULLUP);
    pinMode(SELECT_PIN, INPUT_PULLUP);

    // カードリーダの初期化
    if (!cardReader.init()) {
        error("Can’t init the card.");
    }

    // FATパーティションを検索
    uint8_t partition = 0;
    for (partition = 0; partition < 5; partition++) {
        if (volume.init(cardReader, partition)) {
            break;
        }
    }

    // FATパーティションが見つからなければエラー
    if (partition == 5) {
        error("Can’t find a FAT partition.");
    }

    // ボリュームのルートディレクトリをオープン
    if (!root.openRoot(volume)) {
        error("Can’t open the root.");
    }
}

void loop() {
    uint8_t selectState = digitalRead(SELECT_PIN);
    if (lastSelectState == HIGH && selectState == LOW) {
        soundSelect();
        if (waveFile.isplaying) {
            soundStop();
            soundPlay();
        }
    }
    lastSelectState = selectState;

    uint8_t playState = digitalRead(PLAY_PIN);
    if (lastPlayState == HIGH && playState == LOW) {
        if (waveFile.isplaying) {
            soundStop();
        } else {
            soundPlay();
        }
    }
    lastPlayState = playState;

    if (isPlaying && !waveFile.isplaying) {
        // 曲の再生が終わったら自動的に次の曲を再生する
        soundSelect();
        soundPlay();
    }

    delay(20);
}

void soundPlay() {
    // ファイル名のセット
    strcpy_P(name, (char*)pgm_read_word(&(games[0])));
    name[2] = pgm_read_byte(&number[index]);

    // ルートディレクトリにあるファイルを名前指定でオープン
    if (!playFile.open(root, name)) {
        error("Can’t open the file to play.");
    }

    // プレーヤーにファイルをセット
    if (!waveFile.create(playFile)) {
        error("Not a valid WAV file.");
    }

    // 再生開始
    waveFile.play();

    // 再生用にオープンしたファイルをクローズ
    playFile.close();

    isPlaying = true;
}

void soundStop() {
    waveFile.stop();
    isPlaying = false;
}

void soundSelect() {
    index == 3 ? index = 1 : index++;
}