ESP-WROOM-02で二次元温度センサ（ROBOBA041, Grid-EYE）を使ってみる　中編

#include <Wire.h>
#include <GridEye.h>
#include <ESP8266WiFi.h>
#include <ThingSpeak.h>

// Wifi設定
const char ssid[] = "YourSSID";
const char pass[] = "YourPass";

// ThingSpeak設定
const unsigned long myChannelNumber = xxxxxx;
const char *myWriteAPIKey = "YourApiKey";

// ThingSpeak接続用
WiFiClient client;

GridEye myeye = GridEye(GridEye_DeviceAddress_1);

// ピクセル温度データ保存用
int pixel[64];

void setup(void)
{
    // 起動メッセージ出力
    Serial.begin(115200);
    Serial.println("Hello GridEye!");

    // 接続開始
    WiFi.begin(ssid, pass);
    Serial.print("Wifi connect...");

    while (WiFi.status() != WL_CONNECTED) {
        delay(500);
        Serial.print(".");
    }

    Serial.println("");
    Serial.println("WiFi connected");
    Serial.println("IP address: ");
    Serial.println(WiFi.localIP());

    // I2Cバスに参加
    Wire.begin();
}

void loop(void)
{
    // サーミスタ温度読み出し
    int temp = myeye.thermistorTemp();
    Serial.print(F("Thermistor Temp: "));
    Serial.println(temp * 0.065);   // 1単位 = 0.065度

    // ピクセル温度データ読み出し
    myeye.pixelOut(pixel);
    Serial.println(F("Pixel Output: "));

    for (int i = 0; i < 64; i++) {

        if (i && ((i % 8) == 0)) {
            Serial.println();
        }

        Serial.print(pixel[i] * 0.25);   // 1単位 = 0.25度
        Serial.print(' ');
    }

    Serial.println();

    // センサーデータアップロード開始
    ThingSpeak.begin(client);

    // フィードに値を設定
    String pixelString_1 = String(pixel[0] * 0.25);

    for (int i = 1; i < 32; i++) {
        pixelString_1 += ":" + String(pixel[i] * 0.25);
    }

    String pixelString_2 = String(pixel[32] * 0.25);

    for (int i = 33; i < 64; i++) {
        pixelString_2 += ":" + String(pixel[i] * 0.25);
    }

    ThingSpeak.setField(1, float(temp * 0.065));
    ThingSpeak.setField(2, pixelString_1);
    ThingSpeak.setField(3, pixelString_2);

    // ThingSpeakに送信
    Serial.println();
    Serial.print("Write fields...");
    ThingSpeak.writeFields(myChannelNumber, myWriteAPIKey);
    Serial.println("done");

    // 1分間隔で繰り返し
    delay(60000);
}