音声再生IC NSP2340Aを試す　I2C編

#include <Wire.h>

#define PIN_SW_CH1  PIN_PA6
#define PIN_SW_CH2  PIN_PA7

#define ON  LOW
#define OFF HIGH

#define AUDIO_ADDR 0x20
#define AUDIO_CH1 1
#define AUDIO_CH2 2
#define AUDIO_VOLUME 48

uint8_t sw_ch1 = OFF;
uint8_t sw_ch2 = OFF;
uint8_t prev_sw_ch1 = OFF;
uint8_t prev_sw_ch2 = OFF;

uint16_t num_sound = 1;
bool is_bgm_playing = false;

uint8_t send_cmd(const uint8_t *cmd, uint8_t len) {
  Wire.beginTransmission(AUDIO_ADDR);
  for (uint8_t i = 0; i < len; i++) {
    Wire.write(cmd[i]);
  }
  Wire.endTransmission();

  delay(5);

  Wire.requestFrom(AUDIO_ADDR, 1);
  if (Wire.available()){
    return Wire.read();
  }
  return 0x00;
}

uint8_t calc_checksum(const uint8_t *data, uint8_t len){
  uint16_t sum = 0;
  for(uint8_t i=0; i<len; i++){
    sum += data[i];
  }
  return (uint8_t)(~sum);
}

uint8_t power_down(){
  uint8_t cmd[2];
  cmd[0] = 0x82;
  cmd[1] = calc_checksum(cmd, sizeof(cmd)-1); // cmd[0]~cmd[1]までの2byteのチェックサムを計算
  return send_cmd(cmd, sizeof(cmd));
}

uint8_t power_up(){
  // スリープを復帰させるためだけのコマンドは存在しないので、音量設定で代替
  return set_volume(AUDIO_VOLUME);
}

uint8_t set_auto_sleep_enable(){
  uint8_t cmd[2];
  cmd[0] = 0x83;
  cmd[1] = calc_checksum(cmd, sizeof(cmd)-1); // cmd[0]~cmd[1]までの2byteのチェックサムを計算
  return send_cmd(cmd, sizeof(cmd));
}

uint8_t set_auto_sleep_disable(){
  uint8_t cmd[2];
  cmd[0] = 0x84;
  cmd[1] = calc_checksum(cmd, sizeof(cmd)-1); // cmd[0]~cmd[1]までの2byteのチェックサムを計算
  return send_cmd(cmd, sizeof(cmd));
}

uint8_t set_volume(uint8_t vol){
  if(vol > 128){
    vol = 128;
  }
  uint8_t cmd[3];
  cmd[0] = 0xF0;
  cmd[1] = vol;
  cmd[2] = calc_checksum(cmd, sizeof(cmd)-1); // cmd[0]~cmd[1]までの2byteのチェックサムを計算
  return send_cmd(cmd, sizeof(cmd));
}

uint8_t play_sound(uint8_t ch, uint16_t num_sound){
  uint8_t cmd[5];
  cmd[0] = 0xA0;
  cmd[1] = ch;
  cmd[2] = highByte(num_sound);
  cmd[3] = lowByte(num_sound);
  cmd[4] = calc_checksum(cmd, sizeof(cmd)-1); // cmd[0]~cmd[3]までの4byteのチェックサムを計算
  return send_cmd(cmd, sizeof(cmd));
}

uint8_t stop_sound(uint8_t ch){
  uint8_t cmd[3];
  cmd[0] = 0xA1;
  cmd[1] = ch;
  cmd[2] = calc_checksum(cmd, sizeof(cmd)-1); // cmd[0]~cmd[1]までの2byteのチェックサムを計算
  return send_cmd(cmd, sizeof(cmd));
}

uint8_t pause_sound(uint8_t ch){
  uint8_t cmd[3];
  cmd[0] = 0xA2;
  cmd[1] = ch;
  cmd[2] = calc_checksum(cmd, sizeof(cmd)-1); // cmd[0]~cmd[1]までの2byteのチェックサムを計算
  return send_cmd(cmd, sizeof(cmd));
}

uint8_t resume_sound(uint8_t ch){
  uint8_t cmd[3];
  cmd[0] = 0xA3;
  cmd[1] = ch;
  cmd[2] = calc_checksum(cmd, sizeof(cmd)-1); // cmd[0]~cmd[1]までの2byteのチェックサムを計算
  return send_cmd(cmd, sizeof(cmd));
}

/////////////////////////////////////////////////////////////////////////////////////////////

void setup(){
  // 省電力化のため、不要な部分を停止。動作周波数はArduino IDEの方のClock指定で1MHzに落とす
  ADC0.CTRLA &= ~ADC_ENABLE_bm; // ADC(アナログデジタル変換)を停止
  SPI0.CTRLA &= ~SPI_ENABLE_bm; // SPI停止

  Serial.begin(9600); // PB3がRX、PB2がTXになる。Arduino IDEのシリアルモニタ接続用
  Wire.begin();

  pinMode(PIN_SW_CH1, INPUT_PULLUP);
  pinMode(PIN_SW_CH2, INPUT_PULLUP);

  // 省電力化のため、未使用ピンはすべてプルアップする
  pinMode(PIN_PA1, INPUT_PULLUP);
  pinMode(PIN_PA2, INPUT_PULLUP);
  pinMode(PIN_PA3, INPUT_PULLUP);
  pinMode(PIN_PA4, INPUT_PULLUP);
  pinMode(PIN_PA5, INPUT_PULLUP);
  pinMode(PIN_PB4, INPUT_PULLUP);
  pinMode(PIN_PB5, INPUT_PULLUP);
  pinMode(PIN_PC0, INPUT_PULLUP);
  pinMode(PIN_PC1, INPUT_PULLUP);
  pinMode(PIN_PC2, INPUT_PULLUP);
  pinMode(PIN_PC3, INPUT_PULLUP);

  // 起動直後のみ、通信が安定しないのでリトライ処理を入れる。5回まで
  for(uint8_t i=0;i<5;i++){
    delay(500);
    if(set_volume(AUDIO_VOLUME) == 0xA5){
      break; // コマンド正常受付
    }
  }
}

void loop(){
  sw_ch1 = digitalRead(PIN_SW_CH1);
  sw_ch2 = digitalRead(PIN_SW_CH2);

  if(prev_sw_ch1 == OFF && sw_ch1 == ON){
    play_sound(AUDIO_CH1, num_sound);
    Serial.print("Play Sound: ");
    Serial.println(num_sound);
    num_sound++;
    if(num_sound >= 5){
      num_sound = 1;
    }
  }

  if(prev_sw_ch2 == OFF && sw_ch2 == ON){
    if(is_bgm_playing){
      stop_sound(AUDIO_CH2);
      Serial.println("Stop BGM.");
    }else{
      play_sound(AUDIO_CH2, 5);
      Serial.println("Play BGM.");
    }
    is_bgm_playing = !is_bgm_playing;
  }

  prev_sw_ch1 = sw_ch1;
  prev_sw_ch2 = sw_ch2;

  delay(10);
}